"Name"    = 'N-Address Code (NAC)'
"Version" = '0.3.0 (2011/02/08)'
"Author"  = 'Nikolaos Kavvadias <nikolaos.kavvadias@gmail.com>'
"About"   = 'An imperative programming language with light semantics, usable as an executable/interpretable intermediate representation'

! This grammar was (partly) translated from the YACC Meta-language to the GOLD
! Meta-language by the YaccToGOLD utility program.

"Case Sensitive"  = False
"Start Symbol"    = <nac_top>

!{Hex Digit}      = {Digit} + [abcdefABCDEF]
!{Oct Digit}      = [01234567]

{Id Head}         = {Letter} + {Digit} + [_]
{Id Tail}         = {Id Head} + {Digit}

!{String Ch}      = {Printable} - ["]
!{Char Ch}        = {Printable} - ['']

!DecLiteral       = [123456789]{digit}*
!OctLiteral       = 0{Oct Digit}*
!HexLiteral       = 0x{Hex Digit}+
FloatLiteral      = {Digit}*'.'{Digit}+

!StringLiteral    = '"'( {String Ch} | '\'{Printable} )* '"'
!CharLiteral      = '' ( {Char Ch} | '\'{Printable} )''

InitializedArray   = {Id Head}{Id Tail}*'['{Id Head}{Id Tail}*']''=''{'{Id Head}{Id Tail}*(','{Id Head}{Id Tail}*)*'}'
UninitializedArray = ({Id Head}{Id Tail}*'['']' | {Id Head}{Id Tail}*'['{Id Head}{Id Tail}*']')
!T_ID               = Anum | InitializedArray | UninitializedArray | FloatLiteral
T_ID               = {Id Head}{Id Tail}*

!Comment Start    = '/*'
!Comment End      = '*/'
Comment Line       = '//'

T_LPAREN = '('
T_RPAREN = ')'
T_LBRACE = '{'
T_RBRACE = '}'
T_LBRACKET = '['
T_RBRACKET = ']'
T_COMMA = ','
T_COLON = ':'
T_SEMI = ';'
T_ASSIGN = '<='
T_EQUAL = '='
T_PROCEDURE = procedure
T_LOCALVAR = localvar
T_GLOBALVAR = globalvar
T_IN = in
T_OUT = out


! ======================================= Rules

<nac_top>
        ::= <globalvar_def> <procedure_list> 

<globalvar_def>
        ::= 
         |  <globalvar_prefix> <id_list> T_SEMI 
         |  <globalvar_def> <globalvar_prefix> <id_list> T_SEMI 

<globalvar_prefix>
        ::= T_GLOBALVAR <id> 

<procedure_def>
        ::= <procedure_prefix> T_LPAREN <arg_list> T_RPAREN T_LBRACE <localvar_list> <stmt_list> T_RBRACE 

<procedure_list>
        ::= <procedure_def> 
         |  <procedure_list> <procedure_def> 

<procedure_prefix>
        ::= T_PROCEDURE <id> 

<localvar_list>
        ::= 
         |  <localvar_prefix> <id_list> T_SEMI 
         |  <localvar_list> <localvar_prefix> <id_list> T_SEMI 

<localvar_prefix>
        ::= T_LOCALVAR <id> 

<stmt_list>
        ::= 
         |  <stmt_list> <stmt> 

<stmt>
        ::= <nac> 
         |  <pcall> 
         |  <label> 

<nac>
        ::= <opnd_out_list> <assign_op> <id> <opnd_in_list> T_SEMI 
         |  <opnd_out_list> <assign_op> <id> T_SEMI 
         |  <id> <opnd_in_list> T_SEMI 
         |  <id> T_SEMI 

<pcall>
        ::= T_LPAREN <opnd_out_list> T_RPAREN <assign_op> <id> T_LPAREN <opnd_in_list> T_RPAREN T_SEMI 
         |  T_LPAREN <opnd_out_list> T_RPAREN <assign_op> <id> T_SEMI 
         |  <id> T_LPAREN <opnd_in_list> T_RPAREN T_SEMI 

<assign_op>
        ::= T_ASSIGN 

<label>
        ::= <id> T_COLON 

<opnd_out_list>
        ::= <id_list> 

<opnd_in_list>
        ::= <id_list> 

<arg_list>
        ::= 
         |  <arg_in> 
         |  <arg_out> 
         |  <arg_list> T_COMMA <arg_in> 
         |  <arg_list> T_COMMA <arg_out> 

<arg_in>
        ::= T_IN <id> <id> 

<arg_out>
        ::= T_OUT <id> <id> 

<id_list>
        ::= <id> 
         |  <id_list> T_COMMA <id> 

<id>
        ::= T_ID
         |  InitializedArray 
         |  UninitializedArray 
         |  FloatLiteral